Notebook 5 in connection with the paper
"The relationship between Zhedanov's algebra AW(3)
and the double affine Hecke algebra in the rank one case",
SIGMA 3 (2007), 063, 15 pages; arXiv:math.QA/0612730v4,
by Tom H. Koornwinder, T.H.Koornwinder@uva.nl

This checks that the double affine Hecke algebra H-tilde, defined by(3.1)–(3.4), has a representation given by (3.10)–(3.12), and that Y and D, given by (3.7), (3.8), are represented by (3.13), (3.14).
Next, some formulas in the proofs of Propositions (3.1), (3.2) are checked.
Finally, (6.1) and (6.2) are checked for (Subscript[K, 0]), (Subscript[K, 1]) and (Subscript[T, 1]) given by Theorem 6.2 (this is also a consequence of the results of Notebook 2).

Last modified: February 6, 2014

Off[General::spell, General::spell1];

tt1[f_,z_]:=(((a +b) z-(1+a b))/(1-(z^2))) f[z]+(((1-a z) (1-b z))/(1-(z^2)))f[(z^(-1))];
tt0[f_,z_]:=(((q^(-1)) z ((c d+q )z-(c +d) q))/( q-(z^2))) f[z]-(((c-z) (d-z))/(q-(z^2)))f[q (z^(-1))];

tt1[(tt1[f,#]+f[#])&,z]+a b(tt1[f,z]+f[z]);
Simplify[%]
tt0[(tt0[f,#]+f[#])&,z]+(q^(-1))c d(tt0[f,z]+f[z]);
Simplify[%]
tt1[#(tt1[#f[#]&,#]+b f[#])&,z]+a(tt1[(#f[#])&,z]+b f[z]);
Simplify[%]
q tt0[((#)^(-1))(q tt0[((#)^(-1))f[#]&,#]+d f[#])&,z]+c(q tt0[(((#)^(-1))f[#])&,z]+d f[z]);
Simplify[%]

yy[f_,z_]:=(z (1+a b-(a +b) z) ((c +d) q-(c d +q) z) )/(q (1-(z^2)) (q-(z^2)))f[z]+(((1-a z) (1-b z) (1-c z) (1-d z) )/((1-(z^2))  (1-q (z^2))))f[q z]+(((1-a z) (1-b z) ((c +d)q z-(c d+q)))/(q (1-(z^2))  (1-q (z^2))))f[(z^(-1))]+(((c-z) (d-z) (1+a b-(a +b) z))/((1-(z^2)) (q-(z^2)))) f[q (z^(-1))];

yy[f,z]-tt1[tt0[f,#]&,z];
Simplify[%]

yyinv[f_,z_]:=((q z (a+b-(1+a b )z) (c d+q-(c +d )z))/(a b c d (1-(z^2)) (q-(z^2))))f[z]+((q (a q-z) (b q-z) (c-z) (d-z) )/(a b c d ((q^2)-(z^2)) (q-(z^2))))f[(q^(-1))z]+((q (1-a z) (1-b z) (c d+q-(c +d )z))/(a b c d (1-(z^2)) (q-(z^2)))) f[(z^(-1))]-(((q^2) (c-z) (d-z) (q(1+a b )-(a +b )z))/(a b c d ((q^2)-(z^2)) (q-(z^2))))f[q (z^(-1))];

yy[yyinv[f,#]&,z]-f[z];
Simplify[%]
yyinv[yy[f,#]&,z]-f[z];
Simplify[%]

dd[f_,z_]:=(1-q) z (1-a z) (1-b z)(( (q+1) (c d+q)z-q(c+d) (1+(z^2)))/(q (1-(z^2)) (q-(z^2)) (1-q (z^2))))f[(z^(-1))]+(1-q)  z(c-z) (d-z)(((a +b) (q+(z^2))-(a b+1)(q+1)z)/((1-(z^2))(q-(z^2)) ((q^2)-(z^2)) ))f[q (z^(-1))]+((a+b)(c d+q)(q+(z^2))+q(a b+1)(c+d)(1+(z^2))-((q+1)(c d+q)(a b+1)+2q(a+b)(c+d))z)(z/(q (1-(z^2)) (q-(z^2))))f[z]+(((c-z) (d-z)(a q-z) (b q-z)  )/((q-(z^2))((q^2)-(z^2))))f[(q^(-1)) z]+(((1-a z) (1-b z) (1-c z) (1-d z) )/((1-(z^2)) (1-q (z^2))))f[q z];

yy[f,z]+(q^(-1))a b c d yyinv[f,z]-dd[f,z];
Simplify[%]

v[z_]:=(((1-a z)(1-b z)(1-c z)(1-d z))/((1-(z^2))(1-q (z^2))));
ddsym[f_,z_]:=v[z]f[q z]+(1+(q^(-1))a b c d-v[z]-v[(z^(-1))])f[z]+v[(z^(-1))]f[(q^(-1))z];

dd[(f[#]+f[((#)^(-1))])&,z]-ddsym[(f[#]+f[((#)^(-1))])&,z];
Simplify[%]

(tt1[f,z]+a b f[z])-(((1-a z)(1-b z))/(1-(z^2)))(f[(z^(-1))]-f[z]);
Simplify[%]
(tt1[f,z]+ f[z])-((((1-a z)(1-b z))/(1-(z^2)))f[(z^(-1))]-(((a-z)(b-z))/(1-(z^2)))f[z]);
Simplify[%]
(tt0[f,z]+(q^(-1))c d f[z])-(((c-z)(d-z))/(q-(z^2)))(f[z]-f[q (z^(-1))]);
Simplify[%]
(tt0[f,z]+f[z])-((((q-c z)(q-d z))/(q(q-(z^2))))f[z]-((q(c-z)(d-z))/(q(q-(z^2))))f[q (z^(-1))]);
Simplify[%]

e1=a+b+c+d;
e2=a b +a c+a d+b c+b d+c d;
e3=a b c+a b d+a c d+b c d;
e4=a b c d;
bb=(((1-(q^(-1))))^2) (e3+q e1);
cc0=(((q-(q^(-1))))^2);
cc1=(q^(-1))(((q-(q^(-1))))^2)e4;
dd0=-(1/(q^3))(((1-q))^2)  (1+q) (e4+q e2+(q^2));
dd1=-(q^(-3))(((1-q))^2) (1+q) (e1 e4+q e3);
ee=-(q^(-2))(((1-q))^3)(c+d);
ff0=(q^(-3))(((1-q))^3)(1+q)(c d+q) ;
ff1=(q^(-3))(((1-q))^3) (1+q)(a+b) c d;

(q+(q^(-1)))(z+(z^(-1)))dd[(#+((#)^(-1)))f[#]&,z]-(((z+(z^(-1))))^2)dd[f,z]-dd[(((#+((#)^(-1))))^2)f[#]&,z]-(bb(z+(z^(-1)))f[z]+cc0 dd[f,z]+dd0 f[z]+(ee(z+(z^(-1)))+ff0)(tt1[f,z]+ a b f[z]));
Simplify[%]
(q+(q^(-1)))dd[((#+((#)^(-1)))dd[f,#])&,z]-dd[dd[(#+((#)^(-1)))f[#]&,#]&,z]-(z+(z^(-1)))dd[dd[f,#]&,z]-(bb dd[f,z]+cc1(z+(z^(-1)))f[z]+dd1 f[z]+ee dd[(tt1[f,#]+ a b f[#])&,z]+ff1(tt1[f,z]+ a b f[z]));
Collect[%,{f[((q )^2)(z^(-1))],f[q (z^(-1))], f[(z^(-1))],f[(q^(-1)) (z^(-1))],f[(q^(-2))(z^(-1))],f[((q )^2)z],f[q z], f[z],f[(q^(-1)) z],f[(q^(-2)) z]}];
Map[Simplify,%]