Notebook 3 in connection with the paper
"The relationship between Zhedanov's algebra AW(3)
and the double affine Hecke algebra in the rank one case",
SIGMA 3 (2007), 063, 15 pages; arXiv:math.QA/0612730v4,
by Tom H. Koornwinder, T.H.Koornwinder@uva.nl

This defines the double affine Hecke algebra H-tilde (Proposition 5.1) by generators and relations, it shows that, with Y defined by (Subscript[T, 1])(Subscript[T, 0]) , the relations in Proposition 5.2 are also satisfied.

The notebook uses the package NCAlgebra 4.0.6, which can be downloaded from
http://math.ucsd.edu/~ncalg/

Note an error in Proposition 5.1.
In formula (5.6) the factor q in the first term on the right should be (q^(-1)).

Last modified: September 18, 2015

Off[General::spell, General::spell1]

<< NC`;

<<NCAlgebra`;

SNC[tt1,tt0,zz,zzinv];
SetCommutative[q,a,b,c,d];

rel1=zz**zzinv->1;
rel2=zzinv**zz->1;
rel3=tt1**tt1->-(a b+1) tt1-a b;
rel4=tt0**tt0->-((q^(-1))c d+1) tt0-(q^(-1))c d;
rel5=tt1**zz->zzinv**tt1+(a b+1) zzinv-a-b;
rel6=tt1**zzinv->zz**tt1-(a b+1) zzinv+a+b;
rel7=tt0**zz->q zzinv**tt0-((q^(-1))c d+1)zz+(c+d);rel8=tt0**zzinv->(q^(-1)) zz**tt0+(q^(-1))((q^(-1))c d+1) zz-(q^(-1))(c+d);

myrules={rel1,rel2,rel3,rel4,rel5,rel6,rel7,rel8};

tt1inv=-(a^(-1))(b^(-1))tt1-(1+(a^(-1))(b^(-1)));
tt0inv=-q (c^(-1))(d^(-1))tt0-(1+q (c^(-1))(d^(-1)));
yy=tt1**tt0;
yyinv=tt0inv**tt1inv;

NCE[tt1**tt1inv-1];
Sub[%,myrules];
NCE[%]

NCE[tt1inv**tt1-1];
Sub[%,myrules];
NCE[%]

NCE[tt0**tt0inv-1];
Sub[%,myrules];
NCE[%]

NCE[tt0inv**tt0-1];
Sub[%,myrules];
NCE[%]

NCE[yy**zz-(q zz**yy+(1+a b)c d zzinv**yyinv**tt1-(a+b)c d yyinv**tt1-(1+(q^(-1))c d)zzinv**tt1-(1-q)(1+a b)(1+(q^(-1))c d)zzinv+(c+d)tt1+(1-q)(a+b)(1+(q^(-1))c d))];
Sub[%,myrules];
NCE[%];
Sub[%,myrules];
NCE[%]

NCE[yyinv**zz-((q^(-1)) zz**yyinv-(((1+a b) q)/(a b)) zzinv**yyinv**tt1+((a+b)/(a b)) yyinv**tt1+((c d+q)/(a b c d))zzinv**tt1-(((1+a b) (-1+q) (c d+q))/(a b c d))zzinv-((c+d)/(a b c d))tt1+(((1+a b) (c+d) (-1+q))/(a b c d)))];
Sub[%,myrules];
NCE[%];
Sub[%,myrules];
NCE[%]

NCE[yy**zzinv-((q^(-1)) zzinv**yy-(q^(-2))c d(1+a b) zzinv**yyinv**tt1+(q^(-2))(a+b) c d yyinv**tt1+(q^(-1))((q^(-1))c d+1) zzinv**tt1-(q^(-1))(c+d) tt1)];
Sub[%,myrules];
NCE[%];
Sub[%,myrules];
NCE[%]

NCE[yyinv**zzinv-(q zzinv**yyinv+(((1+a b) q)/(a b)) zzinv**yyinv**tt1-((a+b)/(a b))yyinv**tt1-((q(c d+q))/(a b c d))zzinv**tt1+((q (c+d)tt1)/(a b c d)))];
Sub[%,myrules];
NCE[%];
Sub[%,myrules];
NCE[%]