#
#	WINS standard .cshrc file
#	Gert Poletiek, 19 januari 1996
#
#	$Id: cshrc,v 1.9 2004/05/14 09:30:54 janw Exp $
#
umask 022

# softpkg sets the PATH, MANPATH and LD_LIBRARY_PATH variables.
# see man softpkg

if ( -x /usr/local/bin/softpkg ) then
    eval `/usr/local/bin/softpkg -c`
else
    set path = (/bin /usr/local/bin)
    set nosoftpkg
endif

# read additional environment variables from ~/.env.csh

if ( -r ${HOME}/.env.csh ) source ${HOME}/.env.csh

# read aliases from ~/.aliases

if ( -r ${HOME}/.aliases ) source ${HOME}/.aliases

if ( $?prompt ) then
    set cdpath = ( ${HOME} ${HOME}/src )
    set history = 40
    set filec
    set nobeep
    if($?nosoftpkg) then
	set mail = (60 /var/mail/${USER})
    else
	set mail    = ( 60 $MBOX )
	unsetenv MBOX
    endif
    set notify
    if ( $?tcsh ) then
#	set prompt = "(${USER}@%M %h) "
	set prompt = "%M %c: "
	bindkey -e
	bindkey -b ^L   spell-word
	bindkey -b X-^L spell-word
	bindkey -b ^Z   run-fg-editor
	bindkey -b X-^Z run-fg-editor
    else
#	set prompt = "(${USER}@${HOST} \!) "
	set prompt = "(${HOST}@${PATH} \!) "
    endif
endif

# list all possible commands when hitting tab
set autolist